'분류 전체보기' 카테고리의 글 목록 (7 Page)

분류 전체보기

Real Mode -> IA-32e Mode(Long Mode)로 바로 전환하는 예제

kkamagui(까마귀, 한승훈) 2011. 8. 14. 14:24

2011. 8. 14. 14:24

Intel과 AMD에서는 IA-32e Mode, 즉 Long Mode로 전환할 때 Protected Mode(보호 모드)를 거치도록 되어있습니다. 아래 그림은 Intel Manual에서 가져온 Operating Modes Transition Diagram입니다. ^^

위의 그림에서 보면 Real Mode(이하 리얼 모드)에서 IA-32e Mode or Long Mode(이하 IA-32e Mode)로 전환할 때 바로 가는 화살표가 없고 Protected Mode(이하 보호 모드)를 거쳐서 IA-32e 모드로 가게 되어 있습니다.

그.런.데 익명의 제보로 바로 가는 것이 가능하다는 것을 알게 되었습니다. 그래서 구글을 검색해보니 실제로 2005년도에 바로 갈수있는 방법을 찾아내신 분이 있더군요. ^^)-b

OSDev에서 발견했는데, http://forum.osdev.org/viewtopic.php?t=11093에서 그 내용을 보실 수 있습니다. 방법은 비교적 간단합니다. 보호 모드에서 하는 작업을 그대로 리얼 모드에서 한 뒤에 IA-32e 모드로 jump를 하는 것입니다. 아래는 OSDev 링크의 방법을 그대로 옮겨 놓은 것입니다. ^^;;;;

1) Build paging structures (PML4, PDPT, PD and PTs)

2) Enable PAE in CR4

3) Set CR3 so it points to the PML4

4) Enable long mode in the EFER MSR

5) Enable paging and protected mode at the same time (activate long mode)

6) Load a GDT

7) Do a "far jump" to some 64 bit code

때마침 여유가 좀 생겨서 실제로 가능한 예제 코드를 한번 만들어 봤습니다. 기본 뼈대로는 MINT64 OS의 부트 로더 코드와 보호 모드 코드를 사용했고, IA-32e 모드로 전환 가능한지 확인하는 것이 목적이었기 때문에 최소한의 코드만 작성했습니다.

아래는 실제로 동작하는 화면을 캡쳐한 것입니다. QEMU를 사용해서 확인했습니다. ^^

<실제로 QEMU에서 구동한 화면>

리얼 모드에서 보호 모드를 거치지 않고 IA-32e 모드로 전환하는 방법은 Manual에 의해 보장된 방법이 아니므로, 이런 것도 가능하다는 팁 정도로 보시면 될 것 같네요. ^^;;;

그럼 아래에 실제 코드 나갑니다. ^^
(첨부 파일에 소스 코드와 컴파일된 바이너리도 같이 넣어두었으니 참고하시기 바랍니다)

; file      RealMode2IA_32eMode.asm
; date      2011/08/13
; author    kkamagui 
;           Copyright(c)2008 All rights reserved by kkamagui
;			http://www.mint64os.pe.kr
;			
; brief     MINT64 OS의 부트 로더를 일부 수정하여 만든 Real Mode to IA-32e Mode(Long Mode) 예제
;			
;			Real Mode -> Protected Mode -> IA-32e Mode가 아닌 Real Mode -> IA-32e Mode 전환 기법은
;			Intel Manual과 AMD Manual에서 보장하는 방법이 아님을 미리 알려드립니다.
;			어디까지나 이 코드는 Mode 전환이 가능한 것을 확인하는 용도로 작성된 것이니, 
;			팁 정도로 봐주시면 감사하겠습니다.
;			
;			여기에 사용된 코드의 대부분은 제가 작성한 MINT64 OS에서 가져왔습니다.
;			MINT64 OS와 IA-32e Mode(Long Mode or 64bit Mode)에 대한 자세한 내용은 
;			"64비트 멀티코어 OS 원리와 구조" 서적(http://www.yes24.com//24/goods/5271779)을 참고하기 바랍니다.

[ORG 0x00]          ; 코드의 시작 어드레스를 0x00으로 설정
[BITS 16]           ; 이하의 코드는 16비트 코드로 설정

SECTION .text       ; text 섹션(세그먼트)을 정의

jmp 0x07C0:START    ; CS 세그먼트 레지스터에 0x07C0을 복사하면서, START 레이블로 이동

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   코드 영역
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
START:
    mov ax, 0x07C0  ; 부트 로더의 시작 어드레스(0x7C00)를 세그먼트 레지스터 값으로 변환
    mov ds, ax      ; DS 세그먼트 레지스터에 설정
    mov ax, 0xB800  ; 비디오 메모리의 시작 어드레스(0x7C00)를 세그먼트 레지스터 값으로 변환
    mov es, ax      ; ES 세그먼트 레지스터에 설정

; 스택을 0x0000:0000~0x0000:FFFF 영역에 64KB 크기로 생성
    mov ax, 0x0000  ; 스택 세그먼트의 시작 어드레스(0x0000)를 세그먼트 레지스터 값으로 변환
    mov ss, ax      ; SS 세그먼트 레지스터에 설정
    mov sp, 0xFFFE  ; SP 레지스터의 어드레스를 0xFFFE로 설정
    mov bp, 0xFFFE  ; BP 레지스터의 어드레스를 0xFFFE로 설정
    
    ; Interrupt Disable
    cli

mov byte [ es: 0x00 ], 'A'		; Debug
    
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	; PML4 Table, Page Directory Pointer Table, Page Directory 생성
	; PML4부터 0x10000에서 시작하여 4KB씩 할당
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	; 0x10000에 PML4 Table 생성
	mov ax, 0x1000
	mov es, ax			; ES 세그먼트 레지스터에 0x1000을 넣어서 0x10000부터 접근할 수 있도록 함
	mov dword [ es: 0x00 ], 0x11003	; Page Directory Pointer가 있는 0x11000와 P bit, R/W bit를 1로 설정
	mov dword [ es: 0x04 ], 0x00	
	
	; 0x11000에 Page Directory Pointer Table 생성
	mov dword [ es: 0x1000 ], 0x12003	; Page Directory Pointer가 있는 0x12000와 P bit, R/W bit를 1로 설정
	mov dword [ es: 0x1004 ], 0x00	
	
	; 0x12000에 Page Directory 생성
	mov dword [ es: 0x2000 ], 0x0083	; Page Directory의 첫 번째(0~2M)를 Physical 0~2M로 Mapping하고
	mov dword [ es: 0x2004 ], 0x00		; P bit, R/W bit, PS bit를 1로 설정

mov ax, 0xB800
	mov es, ax
    mov byte [ es: 0x00 ], 'B'		; Debug
    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; CR4 컨트롤 레지스터의 PAE 비트와 OSXMMEXCPT 비트, OSFXSR 비트를 1로 설정
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    mov eax, cr4    ; CR4 컨트롤 레지스터의 값을 EAX 레지스터에 저장
    or eax, 0x620   ; PAE 비트(비트 5)와 OSXMMEXCPT 비트(비트 10),
                    ; OSFXSR 비트(비트 9)를 모두 1로 설정 
    mov cr4, eax    ; 설정된 값을 CR4 컨트롤 레지스터에 저장
    
    mov byte [ es: 0x00 ], 'C'		; Debug
	
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; CR3 컨트롤 레지스터에 PML4 테이블의 어드레스 및 캐시 활성화
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    mov eax, 0x10000   	; EAX 레지스터에 PML4 테이블이 존재하는 0x10000를 저장
    mov cr3, eax        ; CR3 컨트롤 레지스터에 0x10000을 저장

mov byte [ es: 0x00 ], 'E'		; Debug

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; IA32_EFER.LME와 IA32_EFER.SCE를 1로 설정하여 IA-32e 모드를 활성화하고 
    ; SYSCALL과 SYSRET 명렁어를 활성화
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    mov ecx, 0xC0000080 ; IA32_EFER MSR 레지스터의 어드레스를 저장
    rdmsr               ; MSR 레지스터를 읽기
        
    or eax, 0x0101      ; EAX 레지스터에 저장된 IA32_EFER MSR의 하위 32비트에서 
                        ; LME 비트(비트 8)와 SCE 비트(비트 0)를 1로 설정
    wrmsr               ; MSR 레지스터에 쓰기
    
    mov byte [ es: 0x00 ], 'F'		; Debug
        
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; CR0 컨트롤 레지스터를 NW 비트(비트 29) = 0, CD 비트(비트 30) = 0, PG 비트(비트 31) = 1로
    ; 설정하여 캐시 기능과 페이징 기능을 활성화하고 TS 비트(비트 3) = 1, EM 비트(비트 2) = 0, 
    ; MP 비트(비트 1) = 1로 설정하여 FPU를 활성화
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    mov eax, cr0            ; EAX 레지스터에 CR0 컨트롤 레지스터를 저장
    or eax, 0xE000000F      ; PE 비트(비트 0), NW 비트(비트 29), CD 비트(비트 30), PG 비트(비트 31),
                            ; TS 비트(비트 3), EM 비트(비트 2), MP 비트(비트 1)을
                            ; 모두 1로 설정
    xor eax, 0x60000004     ; NW 비트(비트 29), CD 비트(비트 30), EM 비트(비트 2),
                            ; EM 비트(비트 2)를 XOR하여 0으로 설정
    mov cr0, eax            ; 설정한 값을 다시 CR0 컨트롤 레지스터에 저장

mov byte [ es: 0x00 ], 'G'		; Debug
    
    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; GDT를 Loading    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    lgdt [ GDTR ]   ; GDTR 자료구조를 프로세서에 설정하여 GDT 테이블을 로드
    
    mov byte [ es: 0x00 ], 'H'		; Debug
    
    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; 로딩한 가상 OS 이미지 실행    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; 커널 코드 세그먼트를 0x00을 기준으로 하는 것으로 교체하고 IP의 값을 0x00을 기준으로 재설정
    ; CS 세그먼트 셀렉터 : IP
    jmp 0x8: ( IA_32eMODE - $$ + 0x7C00 )

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; IA-32e 모드로 진입
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[BITS 64]               ; 이하의 코드는 64비트 코드로 설정
IA_32eMODE:
	mov ax, 0x10		; 커널 데이터 세그먼트로 세그먼트 레지스터를 모두 설정
	mov ds, ax
	mov es, ax
	mov fs, ax
	mov es, ax
	
	mov byte [0xb8000], 'I'		; Debug
	
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
    ; 화면을 모두 지우고 속성을 녹색으로 선택
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	mov esi, 0xB8000              	; SI 레지스터(문자열 원본 인덱스 레지스터)를 초기화
    
.SCREENCLEARLOOP:                   ; 화면을 지우는 루프
    mov byte [ esi ], '.'           ; 비디오 메모리의 문자가 위치하는 어드레스에
                                    ; '.'을 복사하여 문자를 삭제
    mov byte [ esi + 1 ], 0x1A  	; 비디오 메모리의 속성이 위치하는 어드레스에
                                    ; 0x1A(파란 바탕에 밝은 녹색)을 복사

add esi, 2                       ; 문자와 속성을 설정했으므로 다음 위치로 이동

cmp esi, 0xB8000 + (80 * 25 * 2)	; 화면의 전체 크기는 80 문자 * 25 라인임
                             			; 출력한 문자의 수를 의미하는 SI 레지스터와 비교
    jl .SCREENCLEARLOOP      			; SI 레지스터가 80 * 25 * 2보다 작다면 아직 지우지 
                             			; 못한 영역이 있으므로 .SCREENCLEARLOOP 레이블로 이동
    
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
    ; 화면에 잘 전환되었다는 메시지 출력
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	mov esi, MSG1 - $$ + 0x7C00
	mov edi, 0xB8000
	
	; MSG1 출력 루프
PRINTMSG1:
	mov al, byte [ esi ]	; MSG에서 1자를 읽어옴
	cmp al, 0
	je PRINTEND1
	
	mov byte [ edi ], al	; 읽어온 1자를 화면에 출력
	add esi, 1				; MSG는 1 바이트씩 이동
	add edi, 2				; 비디오 메모리는 1바이트 문자 + 1바이트 속성이므로 2바이트 이동
	
	jmp PRINTMSG1

; MSG1 출력 종료	
PRINTEND1:
	
	mov esi, MSG2 - $$ + 0x7C00
	mov edi, 0xB8000 + 320
	
	; MSG2 출력 루프
PRINTMSG2:
	mov al, byte [ esi ]	; MSG에서 1자를 읽어옴
	cmp al, 0
	je PRINTEND2
	
	mov byte [ edi ], al	; 읽어온 1자를 화면에 출력
	add esi, 1				; MSG는 1 바이트씩 이동
	add edi, 2				; 비디오 메모리는 1바이트 문자 + 1바이트 속성이므로 2바이트 이동
	
	jmp PRINTMSG2

; MSG2 출력 종료	
PRINTEND2:
	
	; 무한 루프
	jmp $

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   데이터 영역
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
MSG1 : db	'Real Mode to IA-32e Mode Success. This is IA-32e Mode~!!', 0
MSG2 : db	'Just for testing ^0^)-b', 0

; 아래의 데이터들을 8byte에 맞춰 정렬하기 위해 추가
align 8, db 0

; GDTR의 끝을 8byte로 정렬하기 위해 추가
    dw 0x0000
; GDTR 자료구조 정의
GDTR:
    dw GDTEND - GDT - 1         ; 아래에 위치하는 GDT 테이블의 전체 크기
    dd ( GDT - $$ + 0x7C00 )    ; 아래에 위치하는 GDT 테이블의 시작 어드레스

; GDT 테이블 정의
GDT:
    ; 널(NULL) 디스크립터, 반드시 0으로 초기화해야 함
    NULLDescriptor:
        dw 0x0000
        dw 0x0000
        db 0x00
        db 0x00
        db 0x00
        db 0x00

; IA-32e 모드 커널용 코드 세그먼트 디스크립터
    IA_32eCODEDESCRIPTOR:     
        dw 0xFFFF       ; Limit [15:0]
        dw 0x0000       ; Base [15:0]
        db 0x00         ; Base [23:16]
        db 0x9A         ; P=1, DPL=0, Code Segment, Execute/Read
        db 0xAF         ; G=1, D=0, L=1, Limit[19:16]
        db 0x00         ; Base [31:24]
        
    ; IA-32e 모드 커널용 데이터 세그먼트 디스크립터
    IA_32eDATADESCRIPTOR:
        dw 0xFFFF       ; Limit [15:0]
        dw 0x0000       ; Base [15:0]
        db 0x00         ; Base [23:16]
        db 0x92         ; P=1, DPL=0, Data Segment, Read/Write
        db 0xAF         ; G=1, D=0, L=1, Limit[19:16]
        db 0x00         ; Base [31:24]
GDTEND:

times 510 - ( $ - $$ )    db    0x00    ; $ : 현재 라인의 어드레스
                                        ; $$ : 현재 섹션(.text)의 시작 어드레스
                                        ; $ - $$ : 현재 섹션을 기준으로 하는 오프셋
                                        ; 510 - ( $ - $$ ) : 현재부터 어드레스 510까지
                                        ; db 0x00 : 1바이트를 선언하고 값은 0x00
                                        ; time : 반복 수행
                                        ; 현재 위치에서 어드레스 510까지 0x00으로 채움

db 0x55             ; 1바이트를 선언하고 값은 0x55
db 0xAA             ; 1바이트를 선언하고 값은 0xAA
                    ; 어드레스 511, 512에 0x55, 0xAA를 써서 부트 섹터로 표기함<br/>

그럼 좋은 하루 되세요 ;)

첨부 파일 :

QEMU 0.10.4 버전 압축 파일~!! (6)	2011.09.06
Cygwin으로 64bit Binary가 생성가능한 Cross Compiler 만드는 방법 (21)	2011.09.02
리얼 모드(Real Mode)에서 64비트 모드(IA-32e Mode의 64bit Sub Mode)로 바로 전환하는 방법~!! (0)	2011.08.06
[이벤트] 64비트 멀티코어 OS 원리와 구조 리뷰어 이벤트~!!! (8월 1일까지~!! 지금 바로 신청하세요 ^^) (1)	2011.08.01
MINT64 OS를 공개 프로젝트로 만들려는데, 어디다 올리는게 좋을까요? (17)	2011.07.22

고전과의 만남, 소프트웨어 컨플릭트 2.0~!!! (0)	2011.09.03
7광구를 보고 왔습니다. 나름대로 볼만한 영화더군요. ^^ (2)	2011.08.18
트랜스포머 3, 볼거리는 많지만 조금 아쉬운 스토리~!! (2)	2011.07.02
죽음의 행진(Death March)을 마치고... (2)	2011.06.13
책 "Windows 구조와 원리"로 유명하신 정덕영씨께서 세상을 떠나셨습니다. ㅠㅠ (10)	2011.04.03

윈도우 7에서 TortoiseSVN 설치 시 탐색기에서 아이콘 표시되지 않는 문제 해결 방법 (0)	2011.10.22
윈도우 7에서 telnet이 없다고 나올 때 해결 방법 (2)	2011.10.02
분산 버전 관리 시스템 GIT 설치 방법 및 간단한 사용 방법(Tortoise GIT) (0)	2011.07.24
PNG, JPG <---> ICO 파일로 변환해주는 사이트 (4)	2010.10.28
넥슨(Nexon)에서 게임 개발에 관한 노하우를 공개하는 사이트가 있군요 @0@)-b (5)	2010.06.07

Real Mode -> IA-32e Mode(Long Mode)로 바로 전환하는 예제 (10)	2011.08.14
리얼 모드(Real Mode)에서 64비트 모드(IA-32e Mode의 64bit Sub Mode)로 바로 전환하는 방법~!! (0)	2011.08.06
MINT64 OS를 공개 프로젝트로 만들려는데, 어디다 올리는게 좋을까요? (17)	2011.07.22
[출간] "64비트 멀티코어 OS 원리와 구조"의 부록 CD의 내용을 다운로드하세요~!! (12)	2011.07.07
[출간] "64비트 멀티코어 OS 원리와 구조" 출간 기념 이벤트~!!! (17)	2011.07.06

윈도우 7에서 telnet이 없다고 나올 때 해결 방법 (2)	2011.10.02
윈도우 콘솔창에서 gcc가 실행 안되는 경우 해결 방법과 Cygwin 환경에서 윈도우 디렉터리 접근 방법 (2)	2011.08.08
PNG, JPG <---> ICO 파일로 변환해주는 사이트 (4)	2010.10.28
넥슨(Nexon)에서 게임 개발에 관한 노하우를 공개하는 사이트가 있군요 @0@)-b (5)	2010.06.07
PNG 파일과 JPG, 그리고 GIF을 압축해주는 멋진 사이트 ;) (14)	2009.09.01

7광구를 보고 왔습니다. 나름대로 볼만한 영화더군요. ^^ (2)	2011.08.18
아아... 살다보니 정말 별 일이 다 있네요. ^^;;;;; (28)	2011.08.09
죽음의 행진(Death March)을 마치고... (2)	2011.06.13
책 "Windows 구조와 원리"로 유명하신 정덕영씨께서 세상을 떠나셨습니다. ㅠㅠ (10)	2011.04.03
드디어 파이어폭스 4(Fire Fox 4)가 나왔습니다. ;) (14)	2011.03.27

[출간] "64비트 멀티코어 OS 원리와 구조" 출간 기념 이벤트~!!! (17)	2011.07.06
[출간] "64비트 멀티코어 OS 원리와 구조" 가 드디어 출간되었습니다 ^^ (61)	2011.06.24
[Milestone] 간만에 MINT64 OS를 정리했습니다. ;) (9)	2010.08.22
[Milestone] Milestone과 함께 잠시 돌아왔습니다. ;) (28)	2010.03.28
NASM 컴파일러로 SYSCALL과 SYSRET를 실행할 때 주의할 점... (11)	2009.12.12

안드로이드 OS를 PC에서 실행시켜보자(Android-x86 Project) (12)	2012.03.04
안드로이드에서 "캘린더가 없습니다" 오류 해결 방법 (2)	2011.08.31
안드로이드 앱 개발자 등록시 주의하세요~!! (9)	2010.10.03

드디어 파이어폭스 4(Fire Fox 4)가 나왔습니다. ;) (14)	2011.03.27
코드가 완전하다는 것을 보장할 수 있는 방법이 있을까요? (15)	2011.03.13
[서평] 프로젝트 일대기에 대한 적나라한 보고서 "드리밍 인 코드"~!! (6)	2011.02.21
저는 여전히 하고 싶은 일을 하면서 살고 있습니다 - 2편 (9)	2011.02.12
어흑... ㅠㅠ 무지 정신없고 바쁜 나날을 보내고 있습니다. ㅠㅠ (8)	2011.01.24

코드가 완전하다는 것을 보장할 수 있는 방법이 있을까요? (15)	2011.03.13
[서평] 히가시노 게이고의 신작 - 플래티나 데이터 (2)	2011.02.28
저는 여전히 하고 싶은 일을 하면서 살고 있습니다 - 2편 (9)	2011.02.12
어흑... ㅠㅠ 무지 정신없고 바쁜 나날을 보내고 있습니다. ㅠㅠ (8)	2011.01.24
10년 넘게 함께 살다 간 강아지를 추억하며... (8)	2011.01.04

분류 전체보기

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'프로그래밍(Programming)' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'프로그래밍(Programming)' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'OS Kernel > MINT64 OS' 카테고리의 다른 글

'안드로이드(Android) 개발' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'잡담' 카테고리의 다른 글

'안드로이드(Android) 개발 > 준 컨트롤러 어플' 카테고리의 다른 글

'안드로이드(Android) 개발 > 준 컨트롤러 어플' 카테고리의 다른 글

티스토리툴바